vbscript将图片转换为base64字符串

<%
'vbscript将图片2进制信息转为base64字符，参数FilePath为图片文件物理路径
'@return：ImagesToBase64返回图片base64格式字符串，前缀为data:image/图片类型;base64,base64数据
Function ImagesToBase64(FilePath)
  Dim xml
  Dim root
  Dim fs
  Dim objStream
  Dim objXMLDoc
  Dim Base64

  getFileExt = Mid(FilePath, InstrRev(FilePath, ".") + 1)


  Set objXMLDoc=Server.CreateObject("msxml2.FreeThreadedDOMDocument")
  objXMLDoc.loadXML "<?xml version='1.0'?><Base64Data />"

  Set fs = Server.createObject("Scripting.FileSystemObject") ''FSO组件
  If fs.FileExists(FilePath) Then '判断File文件是否存在
    '用 stream 来读取数据
    Set objStream = Server.CreateObject("ADODB.Stream")
    objStream.Type = 1
    objStream.Open
    objStream.LoadFromFile FilePath


    objXMLDoc.documentElement.dataType = "bin.base64"
    objXMLDoc.documentElement.nodeTypedvalue = objStream.Read
    '数据流读取结束.得到了值 objXMLDoc
    '创建XML文件
    Set xml = Server.CreateObject("msxml2.FreeThreadedDOMDocument")
    xml.load objXMLDoc
    If xml.ReadyState>2 Then
       Set root=xml.getElementsByTagName("Base64Data")
       Base64="data:image/"&getFileExt&";base64,"&root.Item(0).Text
    else
       Base64=""
    End If
    Set xml=Nothing
    Set objStream=Nothing
  else
    Base64=""
  End If
  Set fs=Nothing
  Set objXMLDoc=Nothing
  ImagesToBase64=Base64
End Function

%>

<!--#include file="ImagesToBase64.asp"-->
<%
base64data=ImagesToBase64(Server.MapPath("1.jpg"))
%>
<img src="<%=base64data %>" />